How to query an RDF individual for its data properties?

Question

Hi,

I have an ontology where arc_cfp is an individual of class Arc. I would like to know how could I get all the data properties of the individual, given that I have the individual's URI?

Basically, I am doing this:

SELECT ?idRef ?name ?src ?dst ?perf
WHERE 
{
    ?x rdf:type http://www.semanticweb.org/ontologies/2012/1/graph.owl#arc_cfp .
    ?x graph:idRef_arc ?idRef .
    ?x graph:name_arc ?name .
    ?x graph:hasSource ?src .
    ?x graph:hasDestination ?dst .
    ?x graph:hasPerformatif ?perf .
}

I am pretty sure, using rdf:type is the problem. But, I have no idea what I need to use.

Thanks.

~Codera

Accepted Answer

1

How about

SELECT ?idRef ?name ?src ?dst ?perf
WHERE {
    ?x graph:idRef_arc ?idRef .
    ?x graph:name_arc ?name .
    ?x graph:hasSource ?src .
    ?x graph:hasDestination ?dst .
    ?x graph:hasPerformatif ?perf .
    FILTER(?x=<http://www.semanticweb.org/ontologies/2012/1/graph.owl#arc_cfp>
}

?

link

answered 22 Feb '12, 10:54

database_animal ♦
8.0k●6●12
accept rate: 16%

Answer 2

Or to avoid the FILTER:

SELECT ?idRef ?name ?src ?dst ?perf
WHERE {
   <http://www.semanticweb.org/ontologies/2012/1/graph.owl#arc_cfp> graph:idRef_arc ?idRef .
   <http://www.semanticweb.org/ontologies/2012/1/graph.owl#arc_cfp> graph:name_arc ?name .
   <http://www.semanticweb.org/ontologies/2012/1/graph.owl#arc_cfp> graph:hasSource ?src .
   <http://www.semanticweb.org/ontologies/2012/1/graph.owl#arc_cfp> graph:hasDestination ?dst .
   <http://www.semanticweb.org/ontologies/2012/1/graph.owl#arc_cfp> graph:hasPerformatif ?perf .
}

Or abbreviated:

BASE <http://www.semanticweb.org/ontologies/2012/1/graph.owl#>
SELECT ?idRef ?name ?src ?dst ?perf
WHERE {
   <arc_cfp> graph:idRef_arc ?idRef .
   <arc_cfp> graph:name_arc ?name .
   <arc_cfp> graph:hasSource ?src .
   <arc_cfp> graph:hasDestination ?dst .
   <arc_cfp> graph:hasPerformatif ?perf .
}

Or abbreviated further:

BASE <http://www.semanticweb.org/ontologies/2012/1/graph.owl#>
SELECT ?idRef ?name ?src ?dst ?perf
WHERE {
   <arc_cfp> graph:idRef_arc ?idRef ; 
     graph:name_arc ?name ;
     graph:hasSource ?src ;
     graph:hasDestination ?dst ;
     graph:hasPerformatif ?perf .
}

Or SPARQL 1.1 bind:

BASE <http://www.semanticweb.org/ontologies/2012/1/graph.owl#>
SELECT ?idRef ?name ?src ?dst ?perf
WHERE {
   BIND (<arc_cfp> as >?x)
   ?x graph:idRef_arc ?idRef ; 
     graph:name_arc ?name ;
     graph:hasSource ?src ;
     graph:hasDestination ?dst ;
     graph:hasPerformatif ?perf .
}

Answer 3

Duplicating my answer from StackOverflow:

Assuming you want a purely exploratory query of the form "give me all the triples about a subject" it should look the following:

SELECT *
WHERE
{
  <http://example.org/SomeThing> ?p ?o
}

This will give you all predicate object pairs associated with the constant URI you pass in. If you are interesting in incoming as well as outgoing properties you could do the following instead:

SELECT *
WHERE
{
  { <http://example.org/SomeThing> ?p ?o }
  UNION
  { ?s ?p <http://example.org/SomeThing> }
}

How to query an RDF individual for its data properties?

Follow this question

Upcoming Events

Related questions