Include sub-categories in a DBpedia category SPARQL query

Question

To answer this historical question, I want to query DBpedia for all members of the United States House of Representatives.

Unfortunately, the following DBpedia query does not reach sub-categories and I get only 4 results:

select distinct ?member where {
  ?member
  <http://purl.org/dc/terms/subject>
  <http://dbpedia.org/resource/Category:Members_of_the_United_States_House_of_Representatives>
  .
}

How to get all representatives, including those in sub-categories?

Accepted Answer

Categories are related by the skos:broader property. Until DBpedia supports SPARQL 1.1 property paths, to expand one level of sub-categories try something like:

prefix db: <http://dbpedia.org/ontology/>
prefix dc: <http://purl.org/dc/terms/>
prefix skos: <http://www.w3.org/2004/02/skos/core#>

prefix category: <http://dbpedia.org/resource/Category:>

select distinct ?member where {

    {
        ?member dc:subject category:Members_of_the_United_States_House_of_Representatives .
    } union {
        ?member dc:subject [skos:broader category:Members_of_the_United_States_House_of_Representatives] .
    }

    ?member a db:Person .
}

Answer 2

Generally speaking, what you need is a way to traverse chains of skos:broader relations. SPARQL 1.1 offers the notion of property paths for this, like so:

select distinct ?member where {
  ?member
  <http://purl.org/dc/terms/subject> ?cat .
  ?cat skos:broader* <http://dbpedia.org/resource/Category:Members_of_the_United_States_House_of_Representatives>
}

Unfortunately, the DBPedia endpoint does not yet support this SPARQL 1.1 construction, so this particular solution won't help you immediately. However, the DBPedia endpoint does offer the option of using additional inference rules when evaluating a SPARQL query. In this case, what you want is to have SKOS transitivity rules enabled. You can do this by adapting your query as follows:

DEFINE input:inference "skos-trans"
select distinct ?member where {
  ?member
  <http://purl.org/dc/terms/subject> ?cat .
  ?cat skos:broaderTransitive <http://dbpedia.org/resource/Category:Members_of_the_United_States_House_of_Representatives>
}

Answer 3

To use transitivity in SPARQL on a Virtuoso endpoint (who is use by Dbpedia) you can use an OPTION. Like this :

?categorie skos:broader ?broader 
OPTION(TRANSITIVE, T_DISTINCT, t_in(?categorie), t_out(?broader), t_max(2), t_step('path_id') as ?path, t_step(?categorie) as ?route, t_step('step_no') AS ?jump, T_DIRECTION 2 )

You can use the very helpfull option t_max, who is the number of jump of your recursivity.

P.S : If you have a solution to make a real RDF hierarchy of categories with a CONSTRUCT query, I'm really interested by that :)

Include sub-categories in a DBpedia category SPARQL query

Follow this question

Upcoming Events

Related questions